Inhomogene Differentialgleichung mit der Ansatzmethode

DE = y''[x] - 2  y'[x]

homogene Gleichung

DSolve[DE == 0, y[x], x]

Wir verwenden den Ansatz

ansatz = (a x + b ) Cos[2  x] + (c x + d ) 
          Sin[2  x]

Bevor wir ihn einsetzen, schreiben wir den Ansatz als Funktion:

Function[{x}, Evaluate[ansatz]]

und setzen dies in die inhomogene Differentialgleichung ein:

ausdruck = 
      Expand[DE - 
            x Cos[2  x] /. {y -> 
              Function[{x}, Evaluate[ansatz]]}]

Koeffizientenvergleich liefert

lösung = 
      Solve[Join[CoefficientList[Coefficient[ausdruck, Cos[2  x]], x], 
            CoefficientList[Coefficient[ausdruck, Sin[2  x]], x]] == 
          0, {a, b, c, d}]

Also haben wir die spezielle Lösung der inhomogenen Differentialgleichung gefunden:

ansatz /. lösung[[1]]

Vergleich:

DSolve[y''[x] - 2  y'[x] == x Cos[2  x], y[x], 
      x]

Differentialgleichungssysteme

Übung 13

A=(({{7, -1, 6}, {-10, 4, -12}, {-2, 1, -1}}))

CharacteristicPolynomial[A, λ]

Eigenvalues[A]

system = Eigensystem[A]

Transpose[system[[2]]]

Somit ist die allgemeine Lösung des homogenen Systems gegeben durch

homogenelösung = 
      MapThread[
        Rule, {{y1[x], y2[x], y3[x]}, 
          Transpose[
              system[[2]]] . ({K, L, M}*
                Map[Exp, system[[1]]*x])}]

Probe durch Einsetzen:

{{y1'[x]}, {y2'[x]}, {y3'[x]}} - 
          A . {{y1[x]}, {y2[x]}, {y3[x]}} /. 
        Flatten[{homogenelösung, 
            Map[D[#, x] &, homogenelösung]}] // 
      Simplify

mathematicalösung = 
      DSolve[{y1'[x] == 
            7  y1[x] - y2[x] + 6  y3[x], y2'[x] == -10 y1[x] + 
              4  y2[x] - 12  y3[x], y3'[x] == -2 y1[x] + 
              y2[x] - y3[x]}, {y1[x], y2[x], y3[x]}, x]

ebenfalls Probe durch Einsetzen:

{{y1'[x]}, {y2'[x]}, {y3'[x]}} - 
          A . {{y1[x]}, {y2[x]}, {y3[x]}} /. 
        Flatten[{mathematicalösung, 
            Map[D[#, x] &, mathematicalösung]}] // 
      Simplify

Matrix-Exponentialfunktion

MatrixExp[A x]

Vergleich:

mathematicalösung

Übung 14

Inhomogenes System: Variation der Konstanten

b = {{2 - 7  x}, {10  x - 4}, {2  x - 1}}

ansatz = 
      MapThread[
        Rule, {{y1[x], y2[x], y3[x]}, 
          Transpose[
              system[[2]]] . ({K[x], L[x], M[x]}*
                Map[Exp, system[[1]]*x])}]

Einsetzen in die inhomogene Differentialgleichung liefert:

dgl = {y1'[x], y2'[x], y3'[x]} - 
            A . {y1[x], y2[x], y3[x]} - {2 - 7  x, 10  x - 4, 2  x - 1} /. 
          Flatten[{ansatz, Map[D[#, x] &, ansatz]}] // Simplify

DSolve[Map[# == 0 &, dgl], {K[x], L[x], M[x]}, x]

Lösung mit der Lösungsformel aus der Vorlesung. Das Fundamentalsystem ist gegeben durch

W = Transpose[system[[2]]*Exp[system[[1]]*x]]

Inverse[W]

Inverse[W /. x -> 0]

Inverse[W] . b // Expand

lösung1 = 
      W . (Inverse[
                  W /. x -> 
                      0] . {{y10}, {y20}, {y30}} + (∫_0^x)(Inverse[W] . b /. x -> t) \[DifferentialD]t) // 
        Simplify

Vergleich mit DSolve:

lösung2 = 
      DSolve[{y1'[x] == 
              7  y1[x] - y2[x] + 6  y3[x] + 2 - 7  x, y2'[
                x] == -10 y1[x] + 4  y2[x] - 12  y3[x] + 10  x - 
                4, y3'[x] == -2 y1[x] + y2[x] - y3[x] + 2  x - 
                1, y1[0] == y10, y2[0] == y20, 
            y3[0] == y30}, {y1[x], y2[x], y3[x]}, x] // 
        Simplify

Einsetzen in die inhomogene Differentialgleichung liefert:

{y1'[x], y2'[x], y3'[x]} - 
          A . {y1[x], y2[x], y3[x]} - {2 - 7  x, 10  x - 4, 2  x - 1} /. 
        Flatten[{lösung2, Map[D[#, x] &, lösung2]}] // 
      Simplify

Dasselbe gilt für unsere gefundene Lösung:

lösung1 - ({{y1[x]}, {y2[x]}, {y3[x]}} /. 
            lösung2[[1]]) // Simplify

Funktionentheorie

Plot[(1/(1 + (x^2))), {x, -5, 5}]