Differentialgleichungen

Weitere Beispiele zur Separation der Variablen

DirectionField[DE_,y_[x_],{x_,a_,b_},{y_,c_,d_},options___]:=Module[{g},
g=DE[[2 ]]/.y[x]->y;
VectorPlot[{1,g},{x,a,b},{y,c,d},options]
]

Beispiel 1.21

DE=y'[x]==x ((y[x])^2)

plot1=DirectionField[DE,y[x ],{x,-5,5},{y,-1,1},Frame->True]

Einige Lösungen

DSolve[{DE,y[0]==0},y[x],x]

DSolve[{DE,y[x0]==y0},y[x],x]

lösung=y[x]/.DSolve[{DE,y[0]==k},y[x],x][[1]]

liste=Table[lösung,{k,-3,3,(1/3)}]

plot2=Plot[liste//Evaluate,{x,-5,5},PlotStyle->Thickness[0.003]]

Show[plot1,plot2,PlotRange->{-1,1}]

Beispiel 1.22

DE=y'[x]==((y[x])^2)-a

DSolve[DE,y[x],x]

DSolve[DE/.{a->-1},y[x],x]

DSolve[DE/.{a->1},y[x],x]

DSolve[DE/.{a->0},y[x],x]

Beispiel 1.23

DE=y'[x]==x ((2((y[x])^2)-2y[x]-4)/(2y[x]-1))

plot1=DirectionField[DE,y[x ],{x,-5,5},{y,-5,5},Frame->True]

Einige Lösungen

lösung=y[x]/.DSolve[{DE,y[0]==k},y[x],x]

y[x]/.DSolve[{DE},y[x],x]

liste1=Table[lösung[[1]],{k,-3,3,(1/3)}];

plot2=Plot[liste1//Evaluate,{x,-5,5},PlotStyle->Thickness[0.003]]

liste2=Table[lösung[[2]],{k,-3,3,(1/3)}];

plot3=Plot[liste2//Evaluate,{x,-5,5},PlotStyle->Thickness[0.003]]

Show[plot1,plot2,plot3,PlotRange->{-5,5}]

Beispiel 1.24

DE=y'[x]==Sin[((x+y[x])/2)]-Sin[((x-y[x])/2)]

plot1=DirectionField[DE,y[x ],{x,-5,5},{y,-5,5},Frame->True]

Ältere Versionen von Mathematica finden keine Lösungen, aber Mathematica 5.2:

lösung=y[x]/.DSolve[{DE,y[0]==k},y[x],x]

Mathematica kann auch den Integranden vereinfachen:

DE=Map[TrigExpand,DE]

DSolve[DE,y[x],x]

Wir lösen die Differentialgleichung schrittweise:

gleichung=∫(1/(Sin[(y/2)]))\[DifferentialD]y==∫Cos[(x/2)]\[DifferentialD]x

Solve[gleichung,y]