Homogene lineare Differentialgleichungen

Übungsaufgabe 1

Wir betrachten die Differentialgleichung

DE=y''''[x]+y[x]==0

mit dem charakteristischen Polynom

charpol=DE/.{y[x]->1,Derivative[n_][y][x]->(λ^n)}

Das charakteristische Polynom hat die komplexen Lösungen:

lösung=Solve[charpol]

lösung=MapAll[ComplexExpand,lösung]

Entsprechend erhalten wir die Lösungsbasis der Differentialgleichung DE:

komplexebasis=Map[Exp[# x]&,λ/.lösung]

reellebasis=Union[ComplexExpand[Re[komplexebasis]],ComplexExpand[Im[komplexebasis]]]

reellebasis={reellebasis[[1]],reellebasis[[2]],reellebasis[[4]],reellebasis[[6]]}

DSolve liefert:

DSolve[DE,y[x],x]

Wir lösen nun ein Anfangswertproblem mit y(0)=0, y'(0)=1, y''(0)=0, y'''(0)=1:

WronskiMatrix[basis_,x_]:=Table[D[basis[[k]],{x,j}],{j,0,Length[basis]-1},{k,Length[basis]}]

WronskiDeterminante[basis_,x_]:=Det[WronskiMatrix[basis,x]]

WronskiMatrix[reellebasis,x]/.x->0

gleichungssystem=(WronskiMatrix[reellebasis,x]/.x->0).{{c[1]},{c[2]},{c[3]},{c[4]}}=={{0},{1},{0},{1}}

LinearSolve[(WronskiMatrix[reellebasis,x]/.x->0),{0,1,0,1}]

sol=Solve[Flatten[(WronskiMatrix[reellebasis,x]/.x->0).{{a},{b},{c},{d}}]=={0,1,0,1},{a,b,c,d}]

lösung={a,b,c,d}.reellebasis/.sol[[1]]

Wir setzen die Lösung in die Differentialgleichung ein

ausdruck=DE/.{y->Function[{x},Evaluate[lösung]]}

Simplify[ausdruck]

und berechnen die Anfangswerte:

Table[D[lösung,{x,k}],{k,0,3}]/.x->0

Inhomogene lineare Differentialgleichungen

Beispiel 4.6, Übungsaufgabe 3

Clear[u]

DE=y''[x]+4y'[x]+4y[x]

homogene Gleichung

charpol=DE/.{y[x]->1,Derivative[n_][y][x]->(λ^n)}

Solve [charpol==0,λ]

DSolve[DE==0,y[x],x]

Iterative Methode: Wir lösen (nach Faktorisierung) zuerst eine inhomogene Differentialgleichung erster Ordnung:

lösung=DSolve[u'[x]+2u[x]==((E^(-2x))/(x^2)),u [x],x]

U[x_]=Evaluate[u[x]/.lösung[[1]]/.C[1]->0]

und finden im zweiten Schritt eine spezielle Lösung der inhomogenen Differentialgleichung:

DSolve[y'[x]+2y[x]==U[x],y[x],x]

Vergleich: DSolve

DSolve[DE==((E^(-2x))/(x^2)),y[x],x]

Ansatzmethode

Beispiel (a):

DE=y''''[x]-5y''[x]+4y[x]

homogene Gleichung

DSolve[DE==0,y[x],x]

inhomogene Gleichung

Lösung=DSolve[DE==1+x+(x^2),y[x],x]

Wir verwenden den Ansatz

ansatz=a (x^2)+b x +c

Bevor wir ihn einsetzen, schreiben wir den Ansatz als Funktion:

Function[{x},Evaluate[ansatz]]

und setzen dies in die inhomogene Differentialgleichung ein:

ausdruck=DE-(1+x+(x^2))/.{y->Function[{x},Evaluate[ansatz]]}

Koeffizientenvergleich liefert

lösung=Solve[CoefficientList[ausdruck,x]==0,{a,b,c}]

Also haben wir die spezielle Lösung der inhomogenen Differentialgleichung gefunden:

ansatz/.lösung[[1]]

Vergleich:

Lösung

(b)

DE=y'''[x]-y'[x]

homogene Gleichung

DSolve[DE==0,y[x],x]

inhomogene Gleichung

Lösung=DSolve[DE==(E^x)+(E^(2x)),y[x],x]

Wir verwenden den Ansatz

ansatz=a (E^(2x))+b x (E^x)

und setzen dies in die inhomogene Differentialgleichung ein:

ausdruck=DE-((E^x)+(E^(2x)))/.{y->Function[{x},Evaluate[ansatz]]}

Koeffizientenvergleich liefert

lösung=Solve[{Coefficient[ausdruck,(E^x)],Coefficient[ausdruck,(E^(2x))]}==0,{a,b}]

Also haben wir die spezielle Lösung der inhomogenen Differentialgleichung gefunden:

ansatz/.lösung[[1]]

Vergleich:

Lösung

(c)

DE=y''[x]-3y'[x]+2y[x]

homogene Gleichung

DSolve[DE==0,y[x],x]

inhomogene Gleichung

Lösung=DSolve[DE==Sin[x],y[x],x]

Wir verwenden den Ansatz

ansatz=a Sin[x]+b Cos[x]

und setzen dies in die inhomogene Differentialgleichung ein:

ausdruck=DE-(Sin[x])/.{y->Function[{x},Evaluate[ansatz]]}

Koeffizientenvergleich liefert

lösung=Solve[{Coefficient[ausdruck,Sin[x]],Coefficient[ausdruck,Cos[x]]}==0,{a,b}]

Also haben wir die spezielle Lösung der inhomogenen Differentialgleichung gefunden:

ansatz/.lösung[[1]]

Vergleich:

Lösung

Hausaufgabe: Ansatzverfahren für Differentialgleichung

DE=y'''[x]-y[x]==(E^x)+(E^(2x))

charakteristisches Polynom

charpol=DE[[1]]/.{y[x]->1,Derivative[n_][y][x]->(λ^n)}

Factor[charpol]

homogene Gleichung

DSolve[DE[[1]]==0,y[x],x]

Wir verwenden den Ansatz

ansatz=(a+b x) (E^x)+c (E^(2x))

Wir setzen dies in die inhomogene Differentialgleichung ein:

ausdruck=Expand[DE[[1]]-DE[[2]]/.Table[D[y[x],{x,k}]-> D[ansatz,{x,k}],{k,0,3}]]

Koeffizientenvergleich liefert

lösung=Solve[Join[CoefficientList[Coefficient[ausdruck,(E^x)],x],CoefficientList[Coefficient[ausdruck,(E^(2x))],x]]==0,{a,b,c}]

Also haben wir die spezielle Lösung der inhomogenen Differentialgleichung gefunden:

ansatz/.lösung[[1]]

Vergleich:

dsol=DSolve[DE,y[x],x]

Simplify[dsol]

Differentialgleichungssysteme

Beispiel 3.1

dgl={y1'[x]==-2y1[x]+y2[x],y2'[x]==-2y2[x]+((Exp[-2x])/x)}

lösung=DSolve[dgl,{y1[x],y2[x]},x]

schrittweise:

lösung2=DSolve[dgl[[2]],y2[x],x]

dgl[[1]]/.lösung2[[1]]

DSolve [dgl[[1]]/.lösung2[[1]],y1[x],x]

Vergleich:

lösung