Clear[ImplicitTaylor]
ImplicitTaylor[F_, y_[x_], y0_, n_] := 
      Module[{ystrich, 
          k}, 
ystrich = -D[F, x]/
            D[F, y]; 
ableitungen = 
          NestList[Together[D[#, x] + D[#, y]*ystrich] &, ystrich, 
            n - 1]; 
y0 + 
          Sum[Limit[Limit[ableitungen[[k]], y -> y0], 
                  x -> 0]/k!*x^k, {k, 1, 
              n}]
]

Clear[ImplicitTaylor2]
ImplicitTaylor2[f_, y_[x_], y0_, n_] := 
      Module[{F, 
            z}, 
F[
              z_] := (f /. y -> z); 
approx = 
            Nest[# - F[#]/F'[#] &, y0, 
              Log[2, n + 1]]; 
approx + 
            O[x]^(n + 1)
] /; 
        IntegerQ[Log[2, n + 1]]

ImplicitTaylor2[(x^2) + (y^2) - 1, y[x], 1, 7]

approx

Clear[ImplicitTaylor3]
ImplicitTaylor3[f_, y_[x_], y0_, n_] := 
      Module[{F, 
            z}, 
F[
              z_] := (f /. y -> z); 
approx = 
            Nest[Together[# - F[#]/F'[#]] &, y0, 
              Log[2, n + 1]]; 
approx + 
            O[x]^(n + 1)
] /; 
        IntegerQ[Log[2, n + 1]]

ImplicitTaylor3[(x^2) + (y^2) - 1, y[x], 1, 7]

approx

ImplicitTaylor3[Log[y] - x, y[x], 1, 7]

ImplicitTaylor3[y (E^y) - x, y[x], 0, 7]

ImplicitTaylor3[(x^2) Log[y] + 1, y[x], 0, 7]

Clear[FastImplicitTaylor]
FastImplicitTaylor[f_, y_[x_], y0_, n_] := 
      Module[{F, z, approx}, 
F[z_] := 
            Normal[(f /. y -> z) + 
                O[x]^(n + 1)]; 
approx = 
            y0; 
Do[
            approx = 
              Normal[# - F[#]/F'[#] &[approx] + 
                  O[x]^(2^k)], 
{k, 1, 
              Log[2, n + 1]}]; 
approx + 
            O[x]^(n + 1)
] /; 
        IntegerQ[Log[2, n + 1]]

Timing[imp1 = 
          ImplicitTaylor[(x^2) + (y^2) - 1, y[x], 1, 63];]

Timing[imp2 = 
          ImplicitTaylor2[(x^2) + (y^2) - 1, y[x], 1, 63];]

Timing[imp3 = 
          ImplicitTaylor3[(x^2) + (y^2) - 1, y[x], 1, 63];]

Timing[imp4 = 
          FastImplicitTaylor[(x^2) + (y^2) - 1, y[x], 1, 63];]

{imp1 - imp2, imp1 - imp3, imp1 - imp4}

Timing[FastImplicitTaylor[(x^2) + (y^2) - 1, y[x], 1, 
          511];]

Timing[Series[(Sqrt[1 - (x^2)]), {x, 0, 511}];]