CA II - Uebungsblatt 08

Aufgabe 1

Prozedur

Clear[kfreieRE]
kfreieRE[f_,{k_,kmax_},{n_,nmax_}]:=kfreieRE[f,{k,kmax},{n,nmax}]=
Module[{variablen,sum,i,j,ansatz,liste,lösung,RE},
variablen=Flatten[Table[a[i,j],{i,0,kmax},{j,0,nmax}]];
ansatz=Sum[a[i,j]*F[n+j,k+i],
{j,0,nmax},{i,0,kmax}];sum=Sum[a[i,j]*FunctionExpand[(f/.{k->k+i,n->n+j})/f],{j,0,nmax},{i,0,kmax}];
sum=Numerator[Together[sum]];
liste=CoefficientList[sum,k];
Off[Solve::"svars"];
lösung=Solve[liste==0,variablen];
On[Solve::"svars"];
lösung=Simplify[lösung];
If[Union[Flatten[Table[a[i,j]/.lösung[[1]],{i,0,kmax},{j,0,nmax}]]]==={0},Return["Es existiert keine solche Rekursion"]];
RE=Numerator[Together[ansatz/.lösung[[1]]]];
RE=Collect[RE,F[__]];
RE=Map[Factor,RE];
RE==0
]

Clear[FasenmyerRE]
FasenmyerRE[f_,{k_,kmax_},{n_,nmax_}]:=Module[{RE,tmp},
RE=kfreieRE[f,{k,kmax},{n,nmax}];
If[RE==="Es existiert keine solche Rekursion",Return["Es existiert keine solche Rekursion"],RE=RE[[1]]];
RE=RE/.{F[n+j_.,k+i_.]->S[n+j]};
tmp=S[n+nmax]/.Solve[RE==0,S[n+nmax]][[1]];
RE=Denominator[tmp]*S[n+nmax]-Numerator[tmp];
RE=Collect[RE,S[___]];
Map[Factor,RE]==0
]

Loesung

RE=FasenmyerRE[(-1)^k Binomial[n,k]^3,{k,3},{n,3}]

RE=RE/.n->n-1

Durch Betrachten des Quotienten S[n+2]/S[n] bekommt man fuer ungerade n

0

da S[1]=0 ist und mit S[0]=1 fuer gerade n

rat=(S[n+2]/.Solve[RE,S[n+2]][[1]])/S[n]/.n->2*m

rat=Factor[rat]

sol=(-27)^m Pochhammer[1/3,m]Pochhammer[2/3,m]/m!^2

Aufgabe 2

Prozedur

Clear[FasenmyerSumDE];
FasenmyerSumDE[f_,x_,k_,xmax_,kmax_,S_]:=Module[{var,ansatz,sum,coeffs,sol,rec,F},var=Flatten[Table[a[i,j],{i,0,xmax},{j,0,kmax}]];
ansatz=Sum[a[i,j]D[F[x,k+j],{x,i}],{i,0,xmax},{j,0,kmax}];
sum=Sum[a[i,j] FunctionExpand[D[f/.k->k+j,{x,i}]/f],{i,0,xmax},{j,0,kmax}];
sum=Numerator[Together[sum]];
coeffs=CoefficientList[sum,k];
Off[Solve::"svars"];
sol=Simplify[Solve[coeffs==0,var]];
If[Union[Flatten[var/.sol[[1]]]]==={0},Return["No differential equation exists!"]];
rec=Numerator[Together[ansatz/.sol[[1]]]];
rec=rec/.{D[F[x,k+j_.],{x,i_}]->D[S[x],{x,i}],F[x,k+j_.]->S[x]};
rec=rec/.a[__]->1;
rec=Collect[rec,D[S[x],{x,_}],Factor];
rec==0]

(a)

FasenmyerSumDE[Binomial[n,k]Binomial[-n-1,k]((1-x)/2)^k,x,k,2,1,P]

Erster Anfangswert: (Subscript[P, n])(0)

P[n,0]=Sum[Binomial[n,k]Binomial[-n-1,k]((1-x)/2)^k,{k,0,Infinity}]/.x->0

FasenmyerRE[P[n,0][[1]],{k,1},{n,2}]

P[0,0]

P[n,0][[1]]/.{n->0,k->0}

P[1,0]

(P[n,0][[1]]/.{n->1,k->0})+(P[n,0][[1]]/.{n->1,k->1})

Folglich ist der erste Anfansgwert P(n,0) 0 für alle ungeraden n und für alle geraden n folgt aus der Rekursion

(-1)^(n/2)Pochhammer[1/2,n/2]/(n/2)!

oder auch

Binomial[-1/2,n/2]

oder auch zusammenfassend und kurz mit Mathematica

LegendreP[n,0]

Zweiter Anfangswert: (Subscript[P, n])'(0)

P'[n,0]=D[Sum[Binomial[n,k]Binomial[-n-1,k]((1-x)/2)^k,{k,0,Infinity}],x]/.x->0

FasenmyerRE[P'[n,0][[1]],{k,1},{n,2}]

P'[0,0]

P'[n,0][[1]]/.{n->0,k->0}

P'[1,0]

(P'[n,0][[1]]/.{n->1,k->0})+(P'[n,0][[1]]/.{n->1,k->1})

Folglich ist der erste Anfangswert P'(n,0) 0 für alle geraden n und für alle ungeraden n folgt aus der Rekursion

(-1)^((n-1)/2)Pochhammer[3/2,(n-1)/2]/((n-1)/2)!

oder auch

Binomial[-3/2,(n-1)/2]

oder auch zusammenfassend und kurz mit Mathematica

D[LegendreP[n,x],x]/.x->0

(b)

FasenmyerSumDE[(-1)^k/((n+k)!k!)(x/2)^(2k+n),x,k,2,1,J]

Anfangswerte

BesselJ[n,1]

D[BesselJ[n,x],x]/.x->1

(c)

FasenmyerSumDE[(-1)^k x^(2k+1)/(2k+1)!,x,k,2,1,F]

Anfangswerte

Sin[x]/.x->0

D[Sin[x],x]/.x->0